; dodana procedura INIT
; dodana struktura PCIR
; dodane dyrektywy kompilacji warunkowej IF/IFE
; obraz pamieci ekranu od adresu B800h (strona zerowa)
; zapisywany na dyskietce w adresie:
; dysk      # =00h {00h..7Fh => FDD; 80h..FFh => HDD}
; glowica   # =00h { 0.. 1}
; cylinder  # =00h {00..79}
; sektor    # =10h {01..18}
; informacja o palecie barw i zestawie znakow nie jest zapisywana,
; w 99 przypadkach na 100 nie jest to wymagane

.186

   ROM_SIZE   equ   1

   ROM   equ   1 ; POST: start -> wyjscie -> zapisanie ekranu po nacisnieciu PRTSCR
   TSR   equ   0 ; DOS: start -> wyjscie -> zapisanie ekranu po nacisnieciu PRTSCR
   EXE   equ   0 ; DOS: start -> zapisanie ekranu -> wyjscie


ROM_CODE        segment use16

CodeSTART:

IFE ROM
        assume CS:ROM_CODE , DS:ROM_CODE , SS:stk

ELSE
        assume CS:ROM_CODE , DS:ROM_CODE
   
         db      55h     ; pierwszy bajt sygnatury
         db      0AAh    ; drugi bajt sygnatury
         db      1       ; ilosc zajetych sektorow po 512 bajtow
         jmp     INIT    ; przejscie do procedury inicjalizacji
   space1      db   (12h) dup (00h)
   PCIR_PTR   dw   20h   ; wskaznik do struktury PCIR
   PNP_PTR      dw   38h   ; wskaznik do sygnatury PNP
   space2      db   (04h) dup (00h)
   PCIR_SIG   db   'PCIR'  ; sygnatura PCIR
   VEN_ID      dw   10ECh   ; VENDOR_ID: realtec
   DEV_ID      dw   8139h   ; DEVICE_ID: rtl8139
   reserved1   dw   0000h
   STRUCT_LEN   dw   0018h   ; dlugosc struktury PCIR (w bajtach)
   STRUCT_VER   db   00h     ; wersja struktury PCIR (aktualnie = 0)
   CLASS_CODE   db   02h   ;
         db   00h   ;
         db   00h   ;
   IMG_LEN      dw   01h
   CODE_DATA_VER   dw   00h
   CODE_TYPE   db   00h   ; 0->x86
   LAST_IMG   db   01h   ; last=1 no=0
   reserved2   dw   0000h

   PNP_SIG      db   '$PnP'   ; sygnatura PnP
   PNP_REV      db   01h   ; rewizja
   PNP_SIZE   db   02h   ; długosc struktury PNP
         dw   0000h   ; offset nastepnej strktury
         db   00h   ; reserved
         db   65h   ; suma kontrolna sygnatury
         dd   00h   ; identyfikator urzadzenia
         dw   00h   ; wskaznik producenta
         dw   00h   ; wskaznik nazwy produktu
         db   02h   ; podstawowa klasa urzadzenia
         db   00h   ; podklasa
         db   00h   ; interfejs programowania
         db   64h   ; wskazniki urzadzenia
         dw   00h   ; BCV
         dw   00h   ; DV
         dw   00h   ; BEP
         dw   00h   ; reserved
         dw   00h   ; SRIV

ENDIF   ;EnfIFrom

;---------------------------------------
; Nowa obsluga przerwania (3 procedury)
;---------------------------------------

;---------------------------------------
; Zapisanie tymczasowego bufora na dysk
;---------------------------------------
SaveStkSect PROC   ;BX<- porzadkowy numer sektora [0..7]
         ;AX<- wskaznik dla tymczasowego sektora w stosie
    push ES
    pusha

    mov SI,9   ; liczba prob

@@Repeat:      ; gdzie dane zostana zapisane:

    mov ch,0   ; {pierwszy cylinder # =00..79}
    mov cl,10  ; {pierwszy sektor  # =01..18}
add cl,BL
    mov dh,0   ; {pierwsza glowica    # = 0..1 }
    mov dl,00h ; {drive #: 00h..7Fh => floppy; 80h..FFh => HDD}
               ; {"A:"=0}

    mov bx,AX  ; {ES:BX poczatek bufora} wskaznik sektora w stosie

    mov ax,SS  ; ES->SS {wszystko pozniej przywrocone przez POP}
    mov es,ax  ;

    mov al, 1  ; 8   ;liczba zapisywanych sektorow:
               ; {dlugosc bufora w sektorach: 80*25*2 div 512=8}

    mov ah,03  ; {funkcja 03h z int13: zapis sektorow z pamieci na dysk}
    int 13h

    jnc @@End  ; jesli nie wystapil blad (CF=0), to koniec ...

    mov AH,0   ; ... w przeciwnym wypadku inicjalizacja podysystemu dyskowego
    mov DL,0
    int 13h
    dec SI     ;

    jnz @@Repeat

@@End:

    popa
    pop ES

    ret
SaveStkSect endp

;===========================================================================
; Kopiowanie sektora (512 bajtow) do bufora tymczasowego polozonego w stosie
;---------------------------------------------------------------------------
copy_sect_2stk proc   ;ax<-SP  bx<-src seg

   push DS      ;save DS ES SI DI CX
   push ES
   push SI
   push DI
   push CX

   mov DS,BX   ;srcSEG->DS
   mov SI,0   ;    00->SI

   mov CX,SS   ;SS->ES
   mov ES,CX   ;
   mov DI,AX   ;SP->DI

   mov CX,200h   ;200h=512
   CLD      ;/ STD
   rep movsb   ;DS:SI >=DF=> ES:DI   

   pop CX      ;restore CX DI SI ES DS
   pop DI
   pop SI
   pop ES
   pop DS

   ret
copy_sect_2stk endp

;=========================================
do_SHOT       proc
        push   AX
   push   BX

;tworzenie tymczasowego bufora w stosie:
;push_512   proc   ;przeznaczenie 512 bajtow miejsca w stosie
   mov   AX,SP   ;upewnienie sie czy SP>200h
   sub   AX,200h
   mov   SP,AX   ;w AX jest wskaznik wykorzystywanego sektora
              ;nalezy wyjasnic, co wskazuje SP: ostatnia liczba w stosie
              ;lub miejsce, gdzie bedzie nastepna liczba ???
;push_512   endp

   mov CX,8
@@PageLoop:
   mov bx,8
   sub bx,cx
   shl bx,5   ;=bx*20:0h ? liczba akapitow od poczatku B800h
   add BX,0B800h

   call   copy_sect_2stk   ; (ax<-SP  bx<-src seg)

   mov BX,8
   sub BX,cx

   call   SaveStkSect   ;BX<- porzadkowy numer sektora [0..7]
            ;AX<- wskaznik tymczasowego bufora w stosie
   loop   @@PageLoop

;usuniecie tymczasowego bufora w stosie:
;pop_512      proc   ;w AX jest wskaznik wykorzystywanego sektora
   mov   AX,SP           ;upewnienie sie czy SP=AX
   add   AX,200h
   mov   SP,AX
;pop_512      endp

   pop   BX
   pop   AX
;----------------------

IF EXE
        mov AX,4C00h   ;exit DOS
        int 21h
ELSE
   IRET   ; powrot z procedury przerwania
ENDIF

do_SHOT       endp
;-------------------------------------------------


vect_num        equ     05h   ; numer przechwytywanego przerwania: 05h wydruk ekranu
;========================================================================================
; zmiana obslugi 5-go przerwania na swoj

; org 200h - aby odciac wszystko co za jednym segmentem
;          - trzeba obliczyc sume kontrolna 2 razy, poki nie uzyjemy.

INIT    PROC
        pusha   ; umieszczenie rejestrow w stosie w nastepujacej kolejnosci:
      ; ax, cx, dx, bx, sp, bp, si, di

        mov     BX, offset do_SHOT   ; wskaznik nowej obslugi przerwania
        mov     DX, CS         ; seg    do_SHOT

        mov     AX, 0
        push    DS
        mov     DS, AX

        mov     SI, vect_num*4
        mov word ptr DS:[SI]  , BX
        mov word ptr DS:[SI+2], DX

        pop DS
        popa

;----------------------
IF TSR
   mov DX,200h   ;stay TSR
   int 27h
ENDIF

IF ROM
   retF   ;wywolanie procedury z BIOS'u
ENDIF

INIT    endp

CodeEND:
        DB (ROM_SIZE*512-(OFFSET CodeEND-OFFSET CodeSTART)-1) DUP (00H)

ChkSum   db 00h   ;bajt, ustawiajacy sume kontrolna modulu w pamieci na zero;
      ;nalezy ja odczytac ponownie po komilacji

ROM_CODE        ends
;==========================================================================================

IFE ROM
stk     segment stack
        db 4096 dup (0)
stk     ends
ENDIF

IF EXE
        end  do_SHOT
ELSE
        end     INIT
ENDIF