@echo off
pushd %~dp0
if not exist bios.bin goto ERR_BNF
echo Creating BIOS backup.
if exist backup.bin del backup.bin
fptw -d backup.bin
if errorlevel 1 goto ERR_BCK
echo Copying GbE MAC address from BIOS backup to bios.bin.
fd44cpr -gn backup.bin bios.bin
if errorlevel 2 goto ERR_CPR
echo Erasing and flashing GbE region from modified bios.bin.
fptw -rewrite -gbe -f bios.bin
if errorlevel 1 goto ERR_FLS
goto EXIT
:ERR_BNF
echo File bios.bin not found. Please copy your BIOS image file to current folder and rename it to bios.bin.
goto EXIT
:ERR_BCK
echo Error occured during backup phase. Exiting.
goto EXIT
:ERR_CPR
echo Error occured during copy phase. Exiting.
goto EXIT
:ERR_FLS
echo Error occured during flash phase.
echo Please run restore.bat to restore BIOS from backup.bin.
:EXIT
echo Thank you for using FTK. Have a nice day.
pause

Рассмотрим, что он делает (тут всё просто, даже всё как надо подписано):
1. Если в текущей папке нет файла "bios.bin", то выходим с ошибкой "File bios.bin not found. Please copy your BIOS image file to current folder and rename it to bios.bin.".
2. Если в текущей папке есть файл "backup.bin", то удаляем его и создаём новый (если не было, то естественно создаём новый).
По сути исполняется команда: fptw -d backup.bin (создаём "backup.bin")
3. Если возникла ошибка во время создания файла "backup.bin", то выходим с ошибкой "Error occured during backup phase. Exiting.".
4. Копируем GbE MAC address из "backup.bin" в "bios.bin".
По сути исполняется команда: fd44cpr -gn backup.bin bios.bin
По другому: копируем MAC из текущей прошивки BIOS в "bios.bin", из которой затем возьмём весь GbE region, но уже именно с Вашим MAC.
5. Если возникла ошибка во время исполнения предыдущей команды, то выходим с ошибкой "Error occured during copy phase. Exiting.".
6. Стираем и прошиваем GbE region из модифицированного файла "bios.bin".
По сути исполняется команда: fptw -rewrite -gbe -f bios.bin
7. Если возникла ошибка во время исполнения предыдущей команды, то выходим с ошибкой: "Error occured during flash phase. Please run restore.bat to restore BIOS from backup.bin.".
8. Выходим с сообщением "Thank you for using FTK. Have a nice day."

Синим я выделил интересующие Вас строки. Но не забудьте, что подразумевается под файлами "backup.bin" и "bios.bin".
И как видно, как раз в "bios.bin" и должен уже быть GbE region новой версии!

А если кратко, то нужно сделать следующее из командной строки (это для понимающих уже, что такое командная строка):
1. В папку с FTK копируем "bios.bin" с новой версией GbE-региона.
2. Создаём "backup.bin" - резервную копию текущей прошивки BIOS. Для этого исполняем команду: fptw -d backup.bin
3. Копируем MAC из "backup.bin" в "bios.bin". Для этого исполняем команду: fd44cpr -gn backup.bin bios.bin
4. Стираем и прошиваем GbE-регион на горячую, т.е. прошиваем прямо в BIOS. Для этого исполняем команду: fptw -rewrite -gbe -f bios.bin