void placeQueenAsm( unsigned col, unsigned ls, unsigned ns, unsigned rs )
{
    int array[4*64];
    __asm
    {
        push    ebp
        lea     edi, array
        mov     ebx, ls
        mov     edx, rs
        mov     esi, ns
        mov     ebp, 0      // ebp = col
place:
        cmp     ebp, N
        jne     cont0
        inc     count
        jmp     exitrecursion
cont0:
        mov     eax, ebx    // row = ls&ns&rs
        and     eax, esi
        and     eax, edx
        stc
        rcl     ebx, 1
        stc
        rcr     edx, 1
        mov     [edi+4], ebx
        mov     [edi+8], esi
        mov     [edi+12], edx
        and     ebp, ebp
        jne     cont1
        mov     ecx, N
        shr     ecx, 1
        shr     eax, cl     // if (!col) row >>= N/2
cont1:
        and     eax, eax
        jz      exitpoint   // while (row)
        mov     ecx, eax
        dec     eax
        and     eax, ecx    // row &= row-1
        xor     ecx, eax    // current = row_old ^ row
        push    eax
        or      eax, ebp
        jne     cont2
        bt      N, 0
        jnc     cont2
        shl     count, 1    // if (!(col||row)&&(N&1)) count <<= 1
cont2:
        pop     eax
        mov     [edi], eax
        add     edi, 16
        inc     ebp
        mov     eax, ecx
        shl     eax, 1
        not     eax
        and     ebx, eax    // ls & ~(current << 1)
        mov     eax, ecx
        shr     eax, 1
        not     eax
        and     edx, eax    // rs & ~(current >> 1)
        not     ecx
        and     esi, ecx    // ns & ~current
        jmp     place
exitpoint:
        and     ebp, ebp
        je      exitPQ
exitrecursion:
        sub     edi, 16
        mov     eax, [edi]
        mov     ebx, [edi+4]
        mov     esi, [edi+8]
        mov     edx, [edi+12]
        dec     ebp
        jmp     cont1
exitPQ:
        pop     ebp
    }
}