; Процедура преобразования двоичного числа в строку символов
; Bход - AX - число
; Bыход - строка по адресу DS:BX
bin2str   proc
            push   dx
            push   cx
            push   bx
            push   si
            push   ax
            mov    cx,6
fill_buff:  mov    byte ptr[bx+1],'' ; Заполнить строку пробелами
            inc    bx
            loop   fill_buff
            mov    si,10        ; |SI|:=10
            or     ax,ax        ; В |AX| - отрицательное число
            jns    clr_div      ; Если +, переход на clr_div
            neg    ax           ; Иначе, меняем знак
clr_div:    sub    dx,dx        ; очистить старшую половину делимого
            div    si           ; |DX:AX| / 10
            add    dx,'0'       ; Преобразовать в символьный вид
            dec    bx           ; |BX|--
            mov    [bx+1],dl    ; Запомнить очередн. цифру в строке
            or     ax,ax        ; В регистре ax - 0?
            jnz    clr_div      ; Если не 0, повторить
            pop    ax           ;
            or     ax,ax        ; Исходное число отрицательно ?
            jns    no_more      ; Если нет, переход к no_more
            dec    bx           ; |BX|--
            mov    byte ptr[bx+1],'-'  ; Поместить в строку знак '-'
no_more:    pop    si
            pop    bx
            mov    byte ptr[bx],6      ; Поместить счетчик символов
            pop    cx
            pop    dx
            ret
bin2str     endp

; Процедура преобразования строки символов в двоичное число
; Bход - DS:BX - адрес строки
; Bыход - AX - число со знаком
str2bin   proc
            push   bx
            push   cx
            sub    AX,AX
            sub    ch,ch
            mov    cl,byte ptr[bx]   ; Счетчик символов - в CX
blanks:     cmp    byte ptr[bx+1],'' ; Цикл пропуска пробелов
            jne    chk_neg
            inc    bx
            loop   blanks
            jmp    good              ; Не обнаружено чисел. результат - 0
; Следующие команды выполняются в случае знака "-"
chk_neg:    cmp    byte ptr[bx+1],'-'
            jne    chk_pos
            inc    bx                ; Продвинуть указатель
            dec    cx                ; Уменьшить счетчик
            call   conv_ab           ; Вызвать программу преобразования
            jc     thru
            cmp    AX,32768          ; Число < -32768
            ja     no_good           ; Да, ошибка
            neg    AX                ; Изменить знак числа
            js     good              ; OK, выходим
; Следующие команды выполняются в случае, если знак не минус
chk_pos:    cmp    byte ptr[bx+1],'+'; sign '+'?
            jne    go_conv   ; Нет, идти на преобразование
            inc    bx        ; Сместить указатель в строке
            dec    cx        ; Уменьшить счетчик символов
go_conv:    call   conv_ab   ; Преобразовать строку в число
            jc     thru      ; В случае ошибки - на выход
            cmp    AX,32767  ; Число не слишком велико?
            ja     no_good   ; Слишком велико, ошибка
good:       clc              ; Очистить флаг CY
            jnc    thru
no_good:    stc              ; Set carry flag
thru:       pop    cx        ; Восстановить значения регистров
            pop    bx
            jmp    skipit
;
; Процедура собственно преобразования числа
conv_ab   proc
            push   bp
            push   bx
            push   si
            mov    bp,bx  ; Поместить указатель на строку в BX
            xor    bx,bx  ; Очистить BX
range:      cmp    byte ptr ds:[bp+1],'0' ; Символ - цифра ?
            jb     non_dig                ; Нет не цифра
            cmp    byte ptr ds:[bp+1],'9' ; Символ > '9'
            jbe    digit                  ; Символ - цифра
non_dig:    stc                     ; Установить флаг ошибки
            jc     end_conv         ; И выйти из процедуры
digit:      mov    si,10
            push   dx            ; Сохранить DX
            mul    si            ; |Ax| * |SI| -> |DX:AX|
            pop    dx            ; Восстановить DX
            mov    bl,ds:[bp+1]  ; Взять очередной символ из строки
            and    bx,0fh        ; Преобразовать символ в двоичное
            add    AX,bx         ; Добавить цифру к старому результату
            jc     end_conv      ; Если результат слишком велик, то выйти
            inc    bp            ; Адрес след цифры в строке
            loop   range         ; Замкнуть цикл по количеству символов
            clc                  ; Сбросить флаг переноса (нет ошибки)
end_conv:   pop    si            ; Восстановить регистры и выйти
            pop    bx
            pop    bp
            ret
conv_ab     endp
skipit:     ret
str2bin     endp

mov [bx][si],ax
add si,2