Function KernelBob(clip a, int topFieldFirst, int kernelDeintThreshold)
{
 a=((topFieldFirst == 1) ? a.AssumeTFF() : a.AssumeBFF())

 b=separatefields(a).trim(1,0).weave()

 a=a.kerneldeint(order=TopFieldFirst, sharp=false, threshold=KernelDeintThreshold)
 b=b.kerneldeint(order=(1-TopFieldFirst), sharp=false, threshold=KernelDeintThreshold)
 
 return interleave(a,b)
}

Function BlendBob(clip c, bool show)
{
 a=c.AssumeFieldBased().Trim(1,0)
 b=c.AssumeFieldBased()

 global a1=a.SelectOdd()
 global a2=a.SelectEven()

 global b1=b.SelectOdd()
 global b2=b.SelectEven()

# Poor man's blending of 2 fields...

 global aw=a.Weave.BilinearResize(a.Width,a.Height)
 global bw=b.Weave.BilinearResize(b.Width,b.Height)

 global aw=(show == false ? aw : aw.Subtitle("a"))
 global bw=(show == false ? bw : bw.Subtitle("b"))

 result=ScriptClip(c.AssumeFPS(c.Framerate/2),"
   ad=Subtract(a1,a2)
   bd=Subtract(b1,b2)

   # Just one metric turned out to be not quite enough so I
   # calculate 5 of them and let the majority decide
   
   global diff1=YPlaneMinMaxDifference(ad, 2)-YPlaneMinMaxDifference(bd, 2)
   global diff2=YPlaneMinMaxDifference(ad, 5)-YPlaneMinMaxDifference(bd, 5)
   global diff3=YPlaneMinMaxDifference(ad,10)-YPlaneMinMaxDifference(bd,10)
   global diff4=YPlaneMinMaxDifference(ad,20)-YPlaneMinMaxDifference(bd,20)
   global diff5=YPlaneMinMaxDifference(ad,50)-YPlaneMinMaxDifference(bd,50)

   pos=0
   neg=0

   pos=pos+(diff1 >= 0 ? 1 : 0)
   pos=pos+(diff2 >= 0 ? 1 : 0)
   pos=pos+(diff3 >= 0 ? 1 : 0)
   pos=pos+(diff4 >= 0 ? 1 : 0)
   pos=pos+(diff5 >= 0 ? 1 : 0)

   neg=neg+(diff1 < 0 ? 1 : 0)
   neg=neg+(diff2 < 0 ? 1 : 0)
   neg=neg+(diff3 < 0 ? 1 : 0)
   neg=neg+(diff4 < 0 ? 1 : 0)
   neg=neg+(diff5 < 0 ? 1 : 0)

   (pos < neg ? aw : bw)

   (" + String(show) + " == false ? last :
     Subtitle(
       chr(32) + chr(32) + chr(32) + chr(32) +
       String(diff1) + chr(32) +
       String(diff2) + chr(32) +
       String(diff3) + chr(32) +
       String(diff4) + chr(32) +
       String(diff5)))
 ")

 return result.AssumeFrameBased().Trim(0,Round(result.FrameCount/2))

}

KernelBob(1,5).BlendBob(false)
Deen("a3d",2,5,5,5)

Потом обычный код