FORMAT  PE GUI 4.0

INCLUDE 'win32wxp.inc'
ENTRY   start

UNICODE_STRING_MAX_BYTES = 65534
UNICODE_STRING_MAX_CHARS = 32767


SECTION '.data' DATA READABLE WRITABLE
cchTextMax      DD      UNICODE_STRING_MAX_CHARS + 1
progManClass    TCHAR   'Progman',0
progManWND      TCHAR   'Program Manager',0
shellDLLClass   TCHAR   'SHELLDLL_DefView',0
sysListView32Class      TCHAR   'SysListView32',0
sysListView32WND        TCHAR   'FolderView',0
regPath         TCHAR   'Software\Ray Adams\ATITrayTools\Profiles\icons\1024x768',0


ALIGN   4
hProgMan        DD      ?
hShellDLL       DD      ?
hSysListView32  DD      ?
nItems          DD      ?
dwExplorerId    DD      ?
hExplorer       DD      ?
lpLvItem        DD      ?
lpItemText      DD      ?
hKey            DD      ?

LABEL   keyBinData      QWORD
        x       DD      ?
        y       DD      ?
itemText        TCHAR   (UNICODE_STRING_MAX_CHARS + 1) DUP (?)


SECTION '.text' CODE EXECUTABLE READABLE
start:
        xor     ebx,ebx

        invoke  FindWindowEx, ebx, ebx, progManClass, progManWND
        test    eax,eax
        jz      @1
        mov     [hProgMan],eax

        invoke  FindWindowEx, [hProgMan], ebx, shellDLLClass, ebx
        test    eax,eax
        jz      @1
        mov     [hShellDLL],eax

        invoke  FindWindowEx, [hShellDLL], ebx, sysListView32Class, sysListView32WND
        test    eax,eax
        jz      @1
        mov     [hSysListView32],eax


        invoke  SendMessage, [hSysListView32], LVM_GETITEMCOUNT, ebx, ebx
        mov     [nItems],eax

        push    ecx
        invoke  GetWindowThreadProcessId, [hSysListView32], esp
        pop     edx
        mov     [dwExplorerId],edx

        invoke  OpenProcess, PROCESS_VM_OPERATION OR PROCESS_VM_READ OR PROCESS_VM_WRITE, ebx, [dwExplorerId]
        test    eax,eax
        jz      @1
        mov     [hExplorer],eax

        invoke  VirtualAllocEx, [hExplorer], ebx, sizeof.LV_ITEM, MEM_COMMIT OR MEM_RESERVE, PAGE_READWRITE
        test    eax,eax
        jz      @2
        mov     [lpLvItem],eax

        invoke  VirtualAllocEx, [hExplorer], ebx, UNICODE_STRING_MAX_BYTES + 2, MEM_COMMIT OR MEM_RESERVE, PAGE_READWRITE
        test    eax,eax
        jz      @3
        mov     [lpItemText],eax


        mov     esi,[nItems]
        mov     edi, [lpLvItem]

        lea     ecx, [edi+LV_ITEM.pszText]
        invoke  WriteProcessMemory, [hExplorer], ecx, lpItemText, 4, ebx
        test    eax,eax
        jz      @4

        lea     ecx, [edi+LV_ITEM.cchTextMax]
        invoke  WriteProcessMemory, [hExplorer], ecx, cchTextMax, 4, ebx
        test    eax,eax
        jz      @4

        invoke  RegOpenKeyEx, HKEY_CURRENT_USER, regPath, ebx, KEY_READ, hKey
        test    eax,eax
        jnz     @4

        invoke  VirtualAllocEx, [hExplorer], ebx, sizeof.RECT, MEM_COMMIT OR MEM_RESERVE, PAGE_READWRITE
        test    eax,eax
        jz      @5
        mov     ebp,eax

get_next:
        sub     esi,1

        invoke  SendMessage, [hSysListView32], LVM_GETITEMTEXTW, esi, edi
        invoke  ReadProcessMemory, [hExplorer], [lpItemText], itemText, UNICODE_STRING_MAX_BYTES + 2, ebx
        test    eax,eax
        jz      @6

        push    8
        invoke  RegQueryValueEx, [hKey], itemText, ebx, ebx, keyBinData, esp
        pop     edx
        test    eax,eax
        jnz     not_found

        invoke  WriteProcessMemory, [hExplorer], ebp, keyBinData, 8, ebx
        test    eax,eax
        jz      @6

        invoke  SendMessage, [hSysListView32], LVM_SETITEMPOSITION32, esi, ebp
        invoke  SendMessage, [hSysListView32], LVM_UPDATE, esi, ebx

not_found:
        test    esi,esi
        jnz     get_next

@6:     invoke  VirtualFreeEx, [hExplorer], ebp, ebx, MEM_RELEASE
@5:     invoke  RegCloseKey, [hKey]
@4:     invoke  VirtualFreeEx, [hExplorer], [lpItemText], ebx, MEM_RELEASE
@3:     invoke  VirtualFreeEx, [hExplorer], [lpLvItem], ebx, MEM_RELEASE
@2:     invoke  CloseHandle,[hExplorer]
@1:     invoke  ExitProcess,ebx


SECTION '.idata' DATA READABLE WRITABLE IMPORT
library kernel32,'KERNEL32.DLL',\
        user32,'USER32.DLL',\
        advapi32,'ADVAPI32.DLL'

INCLUDE 'api\kernel32.inc'
INCLUDE 'api\user32.inc'
INCLUDE 'api\advapi32.inc'