• Процессор:Не менее 1 ГГц или SoC
• ОЗУ: 1 ГБ (для 32-разрядных систем) или 2 ГБ (для 64-разрядных систем)
• Место на жестком диске: 16 ГБ (для 32-разрядных систем) или 20 ГБ (для 64-разрядных систем)
• Видеокарта: DirectX версии 9 или выше с драйвером WDDM 1.0
• Дисплей: 800 x 600

https://www.microsoft.com/ru-ru/software-download/windows10ISO/
Ссылка на бесплатное обновление для людей с огр. возможностями: https://www.microsoft.com/ru-ru/accessi ... s10upgrade

Активация в Windows 10
Установочные ключи Windows 10
На какую версию Windows 10 обновится моя лицензия Windows 7/8.1?
Принцип работы активации продукта. Когда необходимо активировать продукт корпорации Microsoft
Решение проблем с активацией Windows 10
Не работает Media Creation Tool, где скачать образ Windows 10? + другой способ
Работа Fullscreen Optimization в Windows 10 Fall Creators Update
Подробный видеообзор о чистой установке Windows 10 с помощью загрузочной флешки
Обновление зарезервировано, но уведомление не приходит или файлы не скачиваются
Обновление не скачивается или при попытке обновления выдает ошибку 80240020
Автозагрузка или автозапуск приложений в Windows 10
Как сделать резервное копирование и восстановление файлов в Windows 10
Как отключить экран блокировки в Windows 10
Долго грузится папка с видеофайлами, что делать?
Как сделать по умолчанию "Просмотр фотографий Windows" для открытия изображений, если он не отображается в списке
Не работает "Почта", "Календарь" и "Люди". Решение проблемы.
Как отключить Metro приложения в фоне
Скрипт для удаления Metro приложений + другой способ
Как удалить OneDrive?
Настройка способа получения обновлений в Windows 10
Запрет конкретных обновлений Windows и драйверов
Решение проблемы автоподключения VPN-соединения, редактирование скрытых параметров
Решение проблемы с черным экраном при сворачивании игр с помощью Alt-Tab на видеокартах AMD
Windows не видит фотографии на фотоаппарате, решение проблемы
Спящий режим и гибернация: вопросы и ответы
Что такое Fast Boot / Fast Startup / Hybrid Sleep?
Для чего нужен режим CSM в UEFI?

После обновления с Windows 7 или 8.1 для корректной работы Windows 10 желательно переустановить основные драйвера в системе на актуальные версии. Обновление драйверов чипсета на последнюю версию может помочь устранить ошибки в системном журнале Windows, если таковые имеются.
Для материнских плат на чипсете Intel последнюю версию Intel Chipset Driver можно скачать здесь, или версию 10.1.1.9 c сайта Gigabyte здесь.
Для AMD - здесь.

При бесплатном обновлении с Windows 7/8.1 на Windows 10 активация привязывается к Вашему железу. Новый ключ при этом не выдаётся, в обновлённой системе пропишется один из общих ключей. Обновляться можно как через резервирование обновления и Windows Update, так и с помощью Media Creation Tool, образ скачивается тот же.
При чистой установке Windows 10 на ту систему, на которой уже было сделано обновление с предыдущих версий Windows, ключ вводить не требуется. Система активируется автоматически.

Оставляете все настройки в BIOS, а также не отключаете никакие диски - ставите 10-ку, загрузившись с её установочного носителя. В результате у вас должно появиться меню с выбором системы для загрузки. Если приоритетной или последней перед перезагрузкой была 7-ка, то этот выбор ОС будет в старом классическом стиле с белыми буквами на чёрном фоне и перемещаемой полоской выбора. Если же в дефолте загрузка 10-ки или вы перезагружаетесь с 10-ки, то выбор ОС будет на голубом фоне, названия ОС будут в "плитках", курсор мыши вроде бы доступен - уже не помню. Если перезагрузиться с 10-ки и снова её выбрать, получив выбор ОС на голубом фоне, то происходит обычная дальнейшая загрузка 10-ки. Если же выбрать 7-ку, то сначала произойдёт автоматическая перезагрузка компьютера, а потом 7-ка будет сразу загружаться без каких-либо запросов.
Если ваши установленные ОС нормальные, без искажённых загрузчиков и не затвиканы до смерти, то никаких проблем с данным выбором ОС нет и не будет.

Все это справедливо при безупречной работе Win 10. Если будут проблемы с загрузкой, то и Windows 7 Вы загрузить не сможете.
Кроме того, при загрузке через Win 10 ничего, что относится к десятке, удалить не получится. Файлы будут заблокированы системой.
Так что независимая установка тоже имеет свои плюсы. Тут каждый решает сам.
А загрузочные меню и там и там можно легко отредактировать программами типа Виста бут про. С какого бы диска Вы ни грузились, будет выбор обеих систем. © Acsir

У кого стоит Масштабирование х125% (не стандартное х100%) и проблема с замыливанием некоторых окон!
"В Windows 10 и Windows 8.1 используется новая методика масштабирования отображаемых на дисплее шрифтов. Существует возможность вернуться к старому методу масштабирования, используемого в Windows 8 RTM и Windows 7. В большинстве случаев это поможет решить проблему размытости и некорректного отображения шрифтов.
1.Создайте файл revert_classic_dpi.bat со следующим текстом:
REG ADD "HKCU\Control Panel\Desktop" /v DpiScalingVer /t REG_DWORD /d 0x00001018 /f
REG ADD "HKCU\Control Panel\Desktop" /v Win8DpiScaling /t REG_DWORD /d 0x00000001 /f
REG ADD "HKCU\Control Panel\Desktop" /v LogPixels /t REG_DWORD /d 0x00000078 /f
2.Запустите файл revert_classic_dpi.bat с правами администратора.
3.Перезагрузите Windows 10
4.Проверьте, исправилась ли проблема с отображением шрифтов
Примечание. В некоторых случаях значение ключа DpiScalingVer при выходе из системы каждый раз возвращалось на 1000. Надо скопировать созданный bat файл в автозагрузку (Win+R -> shell:startup) и ещё раз перезагрузить компьютер."

xcopy /y /q /v D:\AIO\install.wim D:\AIO\Temp
D:\AIO\DISM\Dism /Mount-Image /ImageFile:D:\AIO\Temp\install.wim /index:1 /MountDir:D:\AIO\Mount
rd /q D:\AIO\Mount\PerfLogs
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Apply-Unattend:D:\AIO\xml\components.xml
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Apply-Unattend:D:\AIO\xml\remove.xml
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-ContactSupport-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-ContactSupport-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-ContactSupport-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-ContactSupport-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-WindowsFeedback-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-WindowsFeedback-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-WindowsFeedback-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-WindowsFeedback-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-OneDrive-Setup-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-OneDrive-Setup-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-Cortana-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-Cortana-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-Cortana-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-Cortana-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-Cortana-PAL-Desktop-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-Cortana-PAL-Desktop-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-Search2-base-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-Search2-base-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-Search2-shell-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-Search2-shell-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-Search2-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-Search2-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-Search2-WOW64-base-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-Search2-WOW64-base-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-Windows-Search2-WOW64-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-Windows-Search2-WOW64-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-OneCore-AllowTelemetry-Reduced-Default-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-OneCore-AllowTelemetry-Reduced-Default-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-OneCore-TroubleShooting-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-OneCore-TroubleShooting-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Microsoft-OneCore-TroubleShooting-WOW64-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Microsoft-OneCore-TroubleShooting-WOW64-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Windows-Defender-AM-Default-Definitions-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Windows-Defender-AM-Default-Definitions-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Windows-Defender-Client-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Windows-Defender-Client-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Windows-Defender-Client-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Windows-Defender-Client-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Windows-Defender-Client-WOW64-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Windows-Defender-Client-WOW64-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Windows-Defender-Client-WOW64-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Windows-Defender-Client-WOW64-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Windows-Defender-Group-Policy-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Windows-Defender-Group-Policy-Package~31bf3856ad364e35~amd64~ru-RU~10.0.10240.16384
D:\AIO\DISM\tweak /p D:\AIO\Mount /c Windows-Defender-Group-Policy-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Image:D:\AIO\Mount /Remove-Package /PackageName:Windows-Defender-Group-Policy-Package~31bf3856ad364e35~amd64~~10.0.10240.16384
D:\AIO\DISM\Dism /Unmount-Image /MountDir:D:\AIO\Mount /commit
D:\AIO\DISM\Dism /Export-Image /SourceImageFile:D:\AIO\Temp\install.wim /SourceIndex:1 /Compress:maximum /DestinationImageFile:D:\AIO\DVD\install.wim
del /q D:\AIO\Temp\install.wim

:: Сделал: Westlife -- ru-board.com --
@Echo off
powercfg.exe /hibernate off
bcdedit /set disabledynamictick yes


:: Команда вызова сценария начала обработки bat файла
call :First


:: Сценарий Меню выбора действий
:Menu
echo.
echo. =============================================
echo. Cтрого для Windows 10 Enterprise LTSB
echo. =============================================
echo.
echo. Разрядность вашей Windows: %xOS%
echo.
echo. Варианты для выбора:
echo.
echo. [1] Spy. (Только отключение слежения, сбора информации
echo. для отправки, и сервисов приложений AppStore)
echo. [2] Settings. (Только применение дополнительных настроек Windows)
echo. [3] Сделать все. (Отключить слежение, AppStore и настроить)
echo. [4] Выйти
echo.
Set /p choice="Ваш выбор: "
if not defined choice goto :Cancell
if "%choice%"=="1" (
goto :Spy
)
if "%choice%"=="2" (
goto :Settings
)
if "%choice%"=="3" (
goto :Spy
)
if "%choice%"=="4" (
goto :Cancell
)
if "%choice%" LEQ "0" (
echo.
echo. Не правильный выбор
echo.
goto :Cancell
)
if "%choice%" GEQ "5" (
echo.
echo. Не правильный выбор
echo.
goto :Cancell
)

:: ------------------------------------------------
:: ---- Ниже начинается 1 часть: Spy ----
:: ------------------------------------------------


:Spy
echo.
echo. =======================================================================
echo. 1 часть: SPY - Отключение слежения, сбора информации и AppStore
echo. =======================================================================
echo.
cd C:\
@Echo on


rem --------------------------------------------------------------------
rem --- Остановка и перевод служб по сбору информации для отправки и ---
rem --- Магазина и приложений AppStore на тип запуска "Отключено": -----

rem --- Служба диагностического отслеживания "DiagTrack" ---
net stop DiagTrack
sc config DiagTrack start= disabled

rem --- Стандартная служба сборщика центра диагностики Microsoft "diagnosticshub.standardcollector.service" ---
net stop diagnosticshub.standardcollector.service
sc config diagnosticshub.standardcollector.service start= disabled

rem --- Служба маршрутизации push-сообщений WAP "dmwappushservice" ---
net stop dmwappushservice
sc config dmwappushservice start= disabled

rem --- Служба DataCollectionPublishingService "DcpSvc" заливает в облако все данные от приложений ---
net stop DcpSvc
sc config DcpSvc start= disabled

rem --- Служба Посредник подключений к сети "NcbService" для Магазина AppStore (хлам) ---
net stop NcbService
sc config NcbService start= disabled

rem --- Службы для Xbox Live ---
sc config XblGameSave start= disabled
sc config XblAuthManager start= disabled

rem --- Служба Диспетчер скачанных карт "MapsBroker" ---
sc config MapsBroker start= disabled

rem --- Служба Магазина Windows AppStore (WSService), (стандартным способом не отключить)---
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\WSService" /v "Start" /t REG_DWORD /d 4 /f

rem --- служба WalletService, "управление" вашими "бабосиками" =) ---
sc config WalletService start= disabled


rem --- Отключение телеметрии и сбора данных для отправки ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\DataCollection" /v "AllowTelemetry" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\SQMClient\Windows" /v "CEIPEnable" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\AppCompat" /v "AITEnable" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\AppCompat" /v "DisableUAR" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\AppCompat" /v "DisableInventory" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\DataCollection" /v "AllowTelemetry" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\WMI\AutoLogger\AutoLogger-Diagtrack-Listener" /v "Start" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\WMI\AutoLogger\SQMLogger" /v "Start" /t REG_DWORD /d 0 /f
DEL /p C:\ProgramData\Microsoft\Diagnosis\ETLLogs\AutoLogger\AutoLogger-Diagtrack-Listener.etl


rem --- Отключение Cortana ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "AllowCortana" /t REG_DWORD /d 0 /f


rem --- Отключение сбора персональных данных, необходимых для "Кортаны" ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Personalization\Settings" /v "AcceptedPrivacyPolicy" /t REG_DWORD /d 0 /f
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\SettingSync\Groups\Language" /v "Enabled" /t REG_DWORD /d 0 /f
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\InputPersonalization" /v "RestrictImplicitInkCollection" /t REG_DWORD /d 1 /f
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\InputPersonalization" /v "RestrictImplicitTextCollection" /t REG_DWORD /d 1 /f
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\InputPersonalization\TrainedDataStore" /v "HarvestContacts" /t REG_DWORD /d 0 /f


rem --- Отключение сбора и передачи набираемых вами текстов ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Input\TIPC" /v "Enabled" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\TabletPC" /v "PreventHandwritingDataSharing" /t REG_DWORD /d 1 /f

rem --- Отключение и сброс собранной информации для предоставления рекламы ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "Enabled" /t REG_DWORD /d 0 /f
if %xOS%==x64 (
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "Enabled" /t REG_DWORD /d 0 /f
)


rem --- Отключение фильтров URL и сбора информации о посещенных сайтах для "SmartScreen" ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\AppHost" /v "EnableWebContentEvaluation" /t REG_DWORD /d 0 /f


rem --- Изменение частоты формирования отзывов на "Никогда" ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Siuf\Rules" /v "NumberOfSIUFInPeriod" /t REG_DWORD /d 0 /f
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Siuf\Rules" /v "PeriodInNanoSeconds" /t REG_DWORD /d 0 /f


rem ----------------------------------------------------------------------------------
rem ----------------------------------------------------------------------------------
rem --- Отключение заданий в планировщике по сбору вашей информации для пересылки: ---
rem --- А также выключение задач для приложений AppStore и Магазина Windows ----------

rem --- Задача, выполняющая сбор данных для SmartScreen ---
schtasks /Change /TN "Microsoft\Windows\AppID\SmartScreenSpecific" /Disable

rem --- Задача агента дистанционного отслеживания влияния на приложения ---
schtasks /Change /TN "Microsoft\Windows\Application Experience\AitAgent" /Disable

rem --- Задачи сбора телеметрических данных программ ---
schtasks /Change /TN "Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser" /Disable
schtasks /Change /TN "Microsoft\Windows\Application Experience\ProgramDataUpdater" /Disable
schtasks /Change /TN "Microsoft\Windows\Application Experience\StartupAppTask" /Disable

rem --- Задача собирает и загружает данные "SQM" (Software Quality Metrics) для программного обеспечения ---
rem --- Одна из задач для "CEIP" (Customer Experience Improvement Program) программа улучшения качества программного обеспечения ---
schtasks /Change /TN "Microsoft\Windows\Autochk\Proxy" /Disable

rem --- Задачи для AppStore ---
schtasks /Change /TN "Microsoft\Windows\CloudExperienceHost\CreateObjectTask" /Disable
schtasks /Change /TN "Microsoft\Windows\Clip\License Validation" /Disable

rem --- Задачи "CEIP" Программы улучшения качества программного обеспечения ---
schtasks /Change /TN "Microsoft\Windows\Customer Experience Improvement Program\Consolidator" /Disable
schtasks /Change /TN "Microsoft\Windows\Customer Experience Improvement Program\KernelCeipTask" /Disable
schtasks /Change /TN "Microsoft\Windows\Customer Experience Improvement Program\UsbCeip" /Disable
schtasks /Change /TN "Microsoft\Windows\Customer Experience Improvement Program\BthSQM" /Disable
schtasks /Change /TN "Microsoft\Windows\Customer Experience Improvement Program\HypervisorFlightingTask" /Disable
schtasks /Change /TN "Microsoft\Windows\DiskDiagnostic\Microsoft-Windows-DiskDiagnosticDataCollector" /Disable
schtasks /Change /TN "Microsoft\Windows\DiskDiagnostic\Microsoft-Windows-DiskDiagnosticResolver" /Disable

rem --- Задача SIUF (System Initiated User Feedback) Обратная связь с пользователями ---
rem --- Помогает понять Microsoft, что вы думаете о различных функциях в операционной системе ---
rem --- И то, что вы, возможно, захотите увидеть в будущем ---
schtasks /Change /TN "Microsoft\Windows\Feedback\Siuf\DmClient" /Disable

rem --- Задачи проверки и обновления Карт AppStore ---
schtasks /Change /TN "Microsoft\Windows\Maps\MapsToastTask" /Disable
schtasks /Change /TN "Microsoft\Windows\Maps\MapsUpdateTask" /Disable

rem --- Задача сборщика полных сведений компьютера и сети ---
schtasks /Change /TN "Microsoft\Windows\NetTrace\GatherNetworkInfo" /Disable

rem --- Задача для "CEIP" ---
schtasks /Change /TN "Microsoft\Windows\PI\Sqm-Tasks" /Disable

rem --- Задача для синхронизации AppSrore приложений ---
schtasks /Change /TN "Microsoft\Windows\SettingSync\NetworkStateChangeTask" /Disable

rem --- Задача автоматически обновляет приложения Магазина Windows ---
schtasks /Change /TN "Microsoft\Windows\WindowsUpdate\Automatic App Update" /Disable

rem --- Задачи обслуживания и проверки лицензий приложений AppStore из Магазина Windows ---
schtasks /Change /TN "Microsoft\Windows\WS\License Validation" /Disable
schtasks /Change /TN "Microsoft\Windows\WS\WSTask" /Disable

rem --- Другие задачи ---
schtasks /Change /TN "Microsoft\Windows\FileHistory\File History (maintenance mode)" /Disable
schtasks /Change /TN "Microsoft\Windows\Maintenance\WinSAT" /Disable
schtasks /Change /TN "Microsoft\Windows\Power Efficiency Diagnostics\AnalyzeSystem" /Disable
schtasks /Change /TN "Microsoft\Windows\Shell\FamilySafetyMonitor" /Disable
schtasks /Change /TN "Microsoft\Windows\Shell\FamilySafetyRefresh" /Disable
schtasks /Change /TN "Microsoft\Windows\Shell\FamilySafetyUpload" /Disable
schtasks /Change /TN "Microsoft\Windows\Windows Error Reporting\QueueReporting" /Disable
schtasks /Change /TN "Microsoft\Windows\Customer Experience Improvement Program\Uploader" /Disable
schtasks /change /TN "Microsoft\Windows\Customer Experience Improvement Program\Consolidator" /Disable
schtasks /Change /TN "Microsoft\Windows\DiskFootprint\Diagnostics" /Disable

rem --- Задача синхронизации AppSrore приложений "BackgroundUploadTask" (отключение под правами SYSTEM) ---
rem --- Файл "Psexec.exe" должен находиться в папке с этим bat файлом ---
@echo off
cd /d %~dp0
chcp 866 >nul
@echo on
psexec -s cmd /c schtasks /Change /TN "Microsoft\Windows\SettingSync\BackgroundUploadTask" /Disable
@echo off
cd C:\
chcp 1251 >nul
@echo on



@Echo off
if "%choice%"=="1" (
echo.
echo. =====================================
echo. Завершена только 1 часть: SPY
echo. =====================================
echo.
echo. Для выхода нажмите любую клавишу.
TIMEOUT /T -1 >nul
exit
) else (echo.
echo. ==============================
echo. Завершена 1 часть: SPY
echo. ==============================
echo.
goto :Settings)


:: -----------------------------------------------
:: --- Ниже начинается 2 часть: Settings ---
:: -----------------------------------------------

:Settings
echo.
echo. ============================================================
echo. 2 часть: Settings - Применение настроек Windows 10
echo. ============================================================
echo.
cd C:\
@Echo on


rem -----------------------------------------------------------------------------------------------------
rem --- Остановка и перевод не обязательных служб по обслуживанию системы на тип запуска "Отключено": ---

rem --- Служба удаленный реестр "RemoteRegistry" ---
net stop RemoteRegistry
sc config RemoteRegistry start= disabled

rem --- Служба общих сетевых ресурсов проигрывателя Windows Media "WMPNetworkSvc" ---
net stop WMPNetworkSvc
sc config WMPNetworkSvc start= disabled

rem --- Служба Windows Search для Индексирования контента "WSearch", "ускоряет" поиск файлов ---
net stop WSearch
sc config WSearch start= disabled

rem --- Служба Немедленные подключения Windows для Windows Connect Now, настраивает параметры точки доступа или WiFi ---
rem --- Используется так же картаной ---
net stop wcncsvc
sc config wcncsvc start= disabled

rem --- Служба Superfetch "SysMain" постоянно, во время простоя, анализирует систему и приложения для ускорения запуска (постоянно насилует диск) ---
net stop SysMain
sc config SysMain start= disabled

rem --- Служба наблюдения за датчиками "SensrSvc" (кооректировка яркости дисплея, поворота экрана и т.д.) ---
net stop SensrSvc
sc config SensrSvc start= disabled

rem --- Биометрическая служба Windows "WbioSrvc" ---
sc config WbioSrvc start= disabled

rem --- Служба "Retail Demo" "скрытый режим для розничной торговли" ---
sc config RetailDemo start= disabled



rem ----------------------------------------------------------------------------------
rem ----------------------------------------------------------------------------------
rem --- Отключение не обязательных заданий в планировщике по обслуживанию системы: ---

rem --- Задача очистки системного диска во время простоя (задолбала постоянно насиловать диск) ---
schtasks /Change /TN "Microsoft\Windows\DiskCleanup\SilentCleanup" /Disable

rem --- Задача оценки объема использования диска ---
schtasks /Change /TN "Microsoft\Windows\DiskFootprint\Diagnostics" /Disable

rem --- Задача копирования файлов пользователя в "резервное" расположение (меню предыдущие версии файлов) ---
rem --- При использовании службы архивации ---
schtasks /Change /TN "Microsoft\Windows\FileHistory\File History (maintenance mode)" /Disable

rem --- Задача измеряет быстродействие и возможности системы ---
schtasks /Change /TN "Microsoft\Windows\Maintenance\WinSAT" /Disable

rem --- Задачи Обслуживания памяти во время простоя и при ошибках ---
schtasks /Change /TN "Microsoft\Windows\MemoryDiagnostic\ProcessMemoryDiagnosticEvents" /Disable
schtasks /Change /TN "Microsoft\Windows\MemoryDiagnostic\RunFullMemoryDiagnostic" /Disable

rem --- Задача анализирования энергопотребления системы ---
schtasks /Change /TN "Microsoft\Windows\Power Efficiency Diagnostics\AnalyzeSystem" /Disable

rem --- Задачи контроля и выполнения семейной безопасности ---
schtasks /Change /TN "Microsoft\Windows\Shell\FamilySafetyMonitor" /Disable
schtasks /Change /TN "Microsoft\Windows\Shell\FamilySafetyRefresh" /Disable

rem --- Задача отправки отчетов об ошибках ---
schtasks /Change /TN "Microsoft\Windows\Windows Error Reporting\QueueReporting" /Disable




rem -----------------------------------------------------------
rem --- Получать обновления только от Microsoft ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\DeliveryOptimization" /v "SystemSettingsDownloadMode" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\DeliveryOptimization" /v "DODownloadMode" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\DeliveryOptimization\Config" /v "DODownloadMode" /t REG_DWORD /d 0 /f
if %xOS%==x64 (
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\DeliveryOptimization\Config" /v "DODownloadMode" /t REG_DWORD /d 0 /f
)


rem --- Отключение Автоматического обновления Windows (включение уведомлений об установке и перезагрузки)---
rem --- Параметры вступают в силу после пере-загрузки и нажатия кнопки проверка наличия обновления!!!! ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "AUOptions" /t REG_DWORD /d 2 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "AutoInstallMinorUpdates" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "EnableFeaturedSoftware" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoRebootWithLoggedOnUsers" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoUpdate" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "ScheduledInstallDay" /t REG_DWORD /d 7 /f


rem --- Отключение поиска драйверов, 2 варианта (первый вариант говорят не работает) ---
rem --- 1). Отключение поиска через центр обновления, эти настройки в: Доп. параметры системы -> Оборудование -> параментры установки устройств ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Device Metadata" /v "PreventDeviceMetadataFromNetwork" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\DriverSearching" /v "SearchOrderConfig" /t REG_DWORD /d 0 /f
rem --- 2). Дополнительно (аналог есть в: gpedit.msc -> Компьютер -> адм. шаблоны -> Система ->
rem --- Управление связью через интернет -> параметры связи -> откл. поиск драйверов ... -> ВКЛючить) ---
rem --- Запретить поиск драверов через центр обновления ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\DriverSearching" /v "DontSearchWindowsUpdate" /t REG_DWORD /d 1 /f


rem --- Отключение получения обновлений для средства удаления "вирусов" ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\MRT" /v "DontOfferThroughWUAU" /t REG_DWORD /d 1 /f


rem --- Отключение поиска в сети из таскбара ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "DisableWebSearch" /t REG_DWORD /d 1 /f


rem --- Отключение поиска через поисковик BING из таскбара ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Search" /v "BingSearchEnabled" /t REG_DWORD /d 0 /f


rem --- Полное отключение OneDrive ---
TASKKILL /F /IM OneDrive.exe /T
reg delete "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "OneDrive" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\OneDrive" /v "DisableFileSyncNGSC" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\OneDrive" /v "DisableLibrariesDefaultSaveToOneDrive" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\OneDrive" /v "DisableMeteredNetworkFileSync" /t REG_DWORD /d 1 /f
reg add "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /v "System.IsPinnedToNameSpaceTree" /t REG_DWORD /d 0 /f
reg add "HKEY_CURRENT_USER\Software\Classes\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /v "System.IsPinnedToNameSpaceTree" /t REG_DWORD /d 0 /f
rem --- Отключение дополнительных скрытых служб, необходимых для OneDrive и синхронизации ---
rem --- Это устраняет ошибку "_Session1" и т.д. при не использовании OneDrive, необходимо выключать вместе с OneDrive ---
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\OneSyncSvc" /v "Start" /t REG_DWORD /d 4 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\OneSyncSvc_Session1" /v "Start" /t REG_DWORD /d 4 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\PimIndexMaintenanceSvc" /v "Start" /t REG_DWORD /d 4 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\PimIndexMaintenanceSvc_Session1" /v "Start" /t REG_DWORD /d 4 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\UnistoreSvc" /v "Start" /t REG_DWORD /d 4 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\UnistoreSvc_Session1" /v "Start" /t REG_DWORD /d 4 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\UserDataSvc" /v "Start" /t REG_DWORD /d 4 /f
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\UserDataSvc_Session1" /v "Start" /t REG_DWORD /d 4 /f
rem --- Дополнительно для x64 по OneDrive ---
if %xOS%==x64 (
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Policies\Microsoft\Windows\Onedrive" /v "DisableFileSyncNGSC" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Policies\Microsoft\Windows\Onedrive" /v "DisableLibrariesDefaultSaveToOneDrive" /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Policies\Microsoft\Windows\Onedrive" /v "DisableMeteredNetworkFileSync" /t REG_DWORD /d 1 /f
reg add "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /v "System.IsPinnedToNameSpaceTree" /t REG_DWORD /d 0 /f
reg add "HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /v "System.IsPinnedToNameSpaceTree" /t REG_DWORD /d 0 /f
)


rem --- Отключить авто-передачу паролей к своим WiFi на сервер Microsoft (WiFiSense)---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\PolicyManager\default\WiFi\AllowAutoConnectToWiFiSenseHotspots" /v "value" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\PolicyManager\default\WiFi\AllowWiFiHotSpotReporting" /v "value" /t REG_DWORD /d 0 /f


rem --- Отключить доступ в интернет службе защиты аудио - Windows Media Digital Rights Management (DRM) ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\WMDRM" /v "DisableOnline" /t REG_DWORD /d 1 /f


rem --- Отключение определения вашего расположения для AppStore и Других программ (Геозона)---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\LocationAndSensors" /v "DisableLocation" /t REG_DWORD /d 1 /f



:: -------------------------------------------------------------------------------
:: ----- Все, что ниже этого сейчас, и что будет добавлено в будущем -----
:: ----- не будет вноситься в файл проверки, можете сами себе добавлять -----



rem --- Открытие проводника на разделе "Этот компьютер" ---
rem --- 1 = Этот компьютер, 2 = Панель быстрого доступа ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "LaunchTo" /t REG_DWORD /d 1 /f


rem --- Отображение значка "Этот компьютер" на рабочем столе ---
rem --- 0 = Включить, 1 = Скрыть ---
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\HideDesktopIcons\NewStartPanel" /v "{20D04FE0-3AEA-1069-A2D8-08002B30309D}" /t REG_DWORD /d 0 /f


rem --- Изменение задержки всплывающих уведомлений панели задач на 10 секунд ---
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "ExtendedUIHoverTime" /t REG_DWORD /d "10000" /f


rem --- Отключение залипания клавиши SHIFT после 5 нажатий ---
rem --- 506 = Выкл, 510 = Включить (По умолчанию) ---
reg add "HKEY_CURRENT_USER\Control Panel\Accessibility\StickyKeys" /v "Flags" /t REG_SZ /d "506" /f


rem --- Отображать скрытые файлы и папки в проводнике ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "Hidden" /t REG_DWORD /d 1 /f


rem --- Отображать расширения файлов в проводнике ---
rem --- 0 = Отображать ---
rem --- 1 = Скрывать ---
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "HideFileExt" /t REG_DWORD /d 0 /f


rem --- Отключение отображения вкладки "предыдущие версии" в свойствах файлов по ПКМ меню ---
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer" /v "NoPreviousVersionsPage" /t REG_DWORD /d 1 /f



REM --- Скрыть опции Bitlocker из ПКМ меню и проводника ---
REM --- Управлять будет можно только через панель управления ---
reg add "HKEY_CLASSES_ROOT\Drive\shell\change-passphrase" /v "LegacyDisable" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\Drive\shell\change-pin" /v "LegacyDisable" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\Drive\shell\manage-bde" /v "LegacyDisable" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\Drive\shell\resume-bde-elev" /v "LegacyDisable" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\Drive\shell\resume-bde" /v "LegacyDisable" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\Drive\shell\encrypt-bde-elev" /v "LegacyDisable" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\Drive\shell\encrypt-bde" /v "LegacyDisable" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\Drive\shell\unlock-bde" /v "LegacyDisable" /t REG_SZ /d "" /f


rem --- Смена имени компьютера. ---
rem --- Чтобы сменилось имя нужно убрать "rem" у строчки ниже и вписать свое имя ---
wmic computersystem where name="%computername%" call rename name="T-778"


@Echo off
if "%choice%"=="2" (
echo.
echo. ==========================================
echo. Завершена только 2 часть: Settings
echo. ==========================================
echo.
echo. Для выхода нажмите любую клавишу.
TIMEOUT /T -1 >nul
exit
) else (echo.
echo. ===========================================
echo. Завершены обе части: Spy и Settings
echo. ===========================================
echo.
echo. Для выхода нажмите любую клавишу.
TIMEOUT /T -1 >nul
exit)


:: ------------------------------------------------
:: ----- Конец 2 части: Settings -----
:: ------------------------------------------------


:: Сценарий для начала бат файла.
:First
@Echo off
chcp 1251 >nul
cd /d %~dp0
Set xOS=x64 & (If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set xOS=x86)

:: Сценарий проверки наличия файла "PsExec.exe" в папке с этим bat файлом.
if not exist PsExec.exe (
echo.
echo. Нет файла "PsExec.exe" в папке с этим bat файлом
echo.
goto :Cancell
) else goto :Admin

:: Сценарий авто-закрытия bat файла при отмене.
:Cancell
echo.
echo. Задачи отменены.
echo.
TIMEOUT /T 5 >nul
exit


:: Сценарий проверки запуска bat файла с правами Администратора.
:Admin
REG QUERY "HKU\S-1-5-19\Environment"
IF NOT %ERRORLEVEL% EQU 0 (
Cls & Echo.
echo. ============================================
echo. Запустить с правами Администратора!
echo. ============================================
TIMEOUT /T 5 >nul & Exit)
Cls
goto :Menu
@pause